video.tcl

# $Id$ #

#
# /** A small gui to dump display windows and encode a video. \file video.tcl \ingroup display */
#

namespace eval display {

    namespace eval video {

  variable convertBin "convert"
  variable mencoderBin "mencoder"
  variable mplayerBin "mplayer"

  variable imagePrefix "display."
  variable imageDir "images"
  variable imageFormat "eps"
  variable imageIndex 0
  variable imageNbDigits "4"
  variable imageTmp "/tmp/display"

  variable videoOutput "display.avi"
  variable videoCodec "mpeg4"
  variable videoFps "15"
  variable videoBitrate "2000"

  variable displayWindow

  proc init {displayWindow_} {
      # This proc shows up a small tk gui: 
      #  - you can easily dump the content of a given display window (eps or png) 
      #  - you can encode/play a video using the images you have
      # dumped, the real work is done by mencoder/mplayer

      variable displayWindow

      set displayWindow $displayWindow_

      set w ".jafarDisplayVideo"
      toplevel $w
      wm title $w "Video"
      wm resizable $w 0 0

      #### dump ####

      set fd "$w.dump"
      labelframe $fd -text "dump"

      set fdf "$fd.filename"
      frame $fdf

      label $fdf.imageDirLabel -text "dir:"
      entry $fdf.imageDir -textvariable ::display::video::imageDir
      label $fdf.imagePrefixLabel -text "prefix:"
      entry $fdf.imagePrefix -textvariable ::display::video::imagePrefix
      label $fdf.imageFormatLabel -text "format:"
      tk_optionMenu $fdf.imageFormat ::display::video::imageFormat "eps" "png"
      label $fdf.imageIndexLabel -text "index:"
      entry $fdf.imageIndex -width $::display::video::imageNbDigits -textvariable ::display::video::imageIndex

      grid $fdf.imageDirLabel $fdf.imageDir
      grid $fdf.imagePrefixLabel $fdf.imagePrefix
      grid $fdf.imageIndexLabel $fdf.imageIndex
      grid $fdf.imageFormatLabel $fdf.imageFormat

      grid configure $fdf.imageDirLabel $fdf.imagePrefixLabel $fdf.imageIndexLabel $fdf.imageFormatLabel -sticky "e"
      grid configure $fdf.imageIndex $fdf.imageFormat -sticky "w"

      grid $fdf -padx 2 -pady 2 -sticky "w"

      button $fd.dump -text "Dump" -command {::display::video::dump}

      grid $fd.dump -padx 2 -pady 2 -sticky "e"

      #### encode ####

      set fe "$w.encode"
      labelframe $fe -text "encode"

      set fef "$fe.filename"
      frame $fef

      label $fef.videoOutputLabel -text "output:" 
      entry $fef.videoOutput -textvariable ::display::video::videoOutput
      label $fef.videoCodecLabel -text "format:"
      tk_optionMenu $fef.videoCodec $::display::video::videoCodec "mpeg4"
      label $fef.videoFpsLabel -text "fps:"
      entry $fef.videoFps -width 5 -textvariable ::display::video::videoFps
      label $fef.videoBitrateLabel -text "bitrate:"
      entry $fef.videoBitrate -width 5 -textvariable ::display::video::videoBitrate

      grid $fef.videoOutputLabel $fef.videoOutput
      grid $fef.videoCodecLabel $fef.videoCodec
      grid $fef.videoFpsLabel $fef.videoFps
      grid $fef.videoBitrateLabel $fef.videoBitrate

      grid configure $fef.videoOutputLabel $fef.videoCodecLabel $fef.videoFpsLabel $fef.videoBitrateLabel -sticky "e"
      grid configure $fef.videoOutput $fef.videoCodec $fef.videoFps $fef.videoBitrate -sticky "w"

      grid $fef -padx 2 -pady 2 -sticky "e"

      button $fe.encode -text "Encode" -command {::display::video::encode}
      button $fe.play -text "Play" -command {::display::video::play}

      grid $fe.encode $fe.play -padx 2 -pady 2 -sticky "e"

      #### buttons ####

      set fc "$w.control"
      frame $fc

      button $fc.close -text "Close" -command "destroy $w"

      grid $fc.close -padx 2 -pady 2

      grid $fd -sticky "we"
      grid $fe -sticky "we"
      grid $fc -sticky "e"

      grid configure $fd $fe $fc -padx 2 -pady 2
  }

  proc dump {} {
      variable imageIndex
      variable imageFormat
      variable imageNbDigits
      variable imageTmp
      variable convertBin
      variable displayWindow

      set index [format "%0${imageNbDigits}d" $imageIndex]
      switch $imageFormat {
    "eps" {display::dumpEps $displayWindow [getImageFilename $index]}
    "png" {
        display::dumpEps $displayWindow ${imageTmp}.eps
        exec $convertBin ${imageTmp}.eps [getImageFilename $index]
        exec rm -f ${imageTmp}.eps
    }
      }
      incr imageIndex
  }

  proc encode {} {
      variable mencoderBin
      variable videoOutput
      variable videoCodec
      variable videoFps
      variable videoBitrate

      switch $videoCodec {
    "mpeg4" {
        set cmd "$mencoderBin mf://[getImageFilename] -mf fps=${videoFps} -ovc lavc -lavcopts vcodec=mpeg4:vbitrate=${videoBitrate} -oac copy -o $videoOutput -ffourcc XVID"
        puts "\n$cmd \n"

        if {[catch "exec $cmd >@stdout 2>@stderr" result]} {
      puts "$result"
        }
    }
      }
  }

  proc play {} {
      variable mplayerBin
      variable videoOutput

      set cmd "$mplayerBin $videoOutput"
      puts "\n$cmd \n"
      
      if {[catch "exec $cmd >@stdout 2>@stderr" result]} {
    puts "$result"
      }
  }

  proc getImageFilename {{index "*"}} {
      variable imageDir
      variable imagePrefix
      variable imageFormat
      
      return [file join $imageDir "${imagePrefix}${index}.${imageFormat}"]  
  }

    }
}

package provide display 1.0