liveDemoLKTracker.tcl

# $Id$ #

namespace eval image  {

    variable capture
    variable captureLoopId
    variable imageGray
    variable lkTracker
    variable doInit "false"

    proc liveDemoLKTracker { {cameraIndex 0} } {
  set w ".lkTraker"
  toplevel $w
  wm title $w "LK tracker"

  button $w.start -text "start" -command "::image::liveDemoLKTrackerStart $cameraIndex"
  button $w.stop -text "stop" -command "::image::liveDemoLKTrackerStop"
  button $w.init -text "init" -command "set ::image::doInit true"
  grid $w.start
  grid $w.stop
  grid $w.init
    }

    proc liveDemoLKTrackerStart { {cameraIndex 0} } {
  variable capture
  variable captureLoopId
  variable imageGray
  variable lkTracker
  variable doInit
  
  package require display

  set capture [image::new_Capture $cameraIndex]
  set image [$capture image]
  set imageGray [image::new_Image [$image width] [$image height] $::image::IPL_DEPTH_8U $::image::JfrImage_CS_GRAY]
  $image convertColorMode $imageGray
  
  set lkTracker [image::new_LKTracker]
  set doInit "true"

  display::show $imageGray
  
  set captureLoopId [after 100 ::image::liveDemoLKTrackerRefresh]
    }

    proc liveDemoLKTrackerRefresh {} {
  variable capture
  variable captureLoopId
  variable imageGray
  variable lkTracker
  variable doInit

  $capture grabFrame
  [$capture image] convertColorMode $imageGray

  if {$doInit} {
      $lkTracker init $imageGray
      set doInit "false"
  } else {
      $lkTracker track $imageGray
  }

  display::clearOverlay $imageGray
  display::refresh $imageGray
  image::lkTrackerDisplayPointsCur $imageGray $lkTracker

  set captureLoopId [after 100 ::image::liveDemoLKTrackerRefresh]
    }

    proc liveDemoLKTrackerStop {} {
  variable capture
  variable captureLoopId
  variable imageGray
  variable lkTracker

  after cancel $captureLoopId
  display::destroy $imageGray
  image::delete_Image $imageGray
  image::delete_Capture $capture
  image::delete_LKTracker $lkTracker
    }

}

package provide image 2.0