display.tcl

# $Id$

# Display module high-level interface

package require image
package require display

namespace eval display  {

    variable imageScale

    proc show { img {title "Jafar"} } {
  # Create a window to display an image

  variable imageScale
  
  set dx [$img width]
  set dy [$img height]
  
  image create photo "photo_$img" -format jfr -data $img
  
  toplevel .$img
  wm title .$img $title
  canvas .$img.$img -width $dx -height $dy
  .$img.$img create image 0 0 -anchor nw -image "photo_$img"
  pack .$img.$img
  bind .$img <Key-q> "::display::destroy $img"
  bind .$img <Key-r> "::display::refresh $img"
  bind .$img <Key-z> "::display::zoom $img 0.5"
  bind .$img <Key-Z> "::display::zoom $img 2"
  # bind .$img <ButtonPress-1> [concat {puts "(%x %y) [} $img {get %x %y ]"}]

  set imageScale($img) "1"
  return $img 
    }

    proc refresh { img } {
  # Refresh the image in a existing window
  variable imageScale

  if {$imageScale($img) != "1"} {
      # reload the (updated) Jafar image into the photo
      image create photo photo_tmp -format jfr -data $img
      # scale it
      tkPhotoScaleCopy photo_tmp "photo_$img" $imageScale($img)
      image delete photo_tmp
  } else {
      # reload the (updated) Jafar image into the photo
      "photo_$img" put $img -format jfr
  }
    }
    
    proc destroy { img } {
  # Destroy a window

  # unmap window
  wm withdraw .$img
  # destroy canvas
  ::destroy .$img.$img
  # destroy toplevel
  ::destroy .$img
  # delete image
  image delete "photo_$img"
    }

    proc blank { img {tag "jafar"} } {
  # blank the display, the image and the overlay
  "photo_$img" blank  
  clearOverlay $img $tag
    }

    proc zoom { img scale } {
  # zoom by scale the display

  variable imageScale
  if {$scale == 1} {return}

  set imageScale($img) [expr $scale * $imageScale($img)]

  refresh $img

  .$img.$img scale all 0 0 $scale $scale 
  .$img.$img configure -width [expr $imageScale($img) * [$img width]] -height [expr $imageScale($img) * [$img height]]
    }

    proc dumpEps { img filename } {
  # dump img (including overlay) to filename in eps format
  update
  .$img.$img postscript -file $filename
    }

    proc dumpAny {img filename } {
  # dump img (including overlay) to filename in any format.
  # The format is guessed from the filename extension, the
  # convertion is made by imagemagick (convert must be in your
  # path)
  
  set imageTmp "/tmp/jafar_display.eps"
  set convertBin "convert"

  display::dumpEps $img $imageTmp

  exec $convertBin $imageTmp $filename
  exec rm -f $imageTmp
    }

    proc showfile { filename } {
    # display an image from a file
      set image [image::Image_loadImage $filename]
      show $image $filename
    }
    proc showseqfile { filenamebase filenamesuffix start end { inc 1 } { nDigit 3 } } {
  # display a sequence of files
  set image [image::Image_loadImage "$filenamebase[format "%0${nDigit}d" $start]$filenamesuffix"]
  set img [show $image $filenamebase]
  for { set i [expr $start+1 ]  } { $i < $end } { set i [expr $i+$inc] } {
      image::delete_Image $image
      set image [image::Image_loadImage "$filenamebase[format "%0${nDigit}d" $i]$filenamesuffix"]
      image create photo "photo_$img" -format jfr -data $image
      wm title .$img "$filenamebase[format "%0${nDigit}d" $i]$filenamesuffix"
      .$img.$img create image 0 0 -anchor nw -image "photo_$img"
      update
  }
    }

}

package provide display 1.0